source: src/models/Axis.pym @ 1315:0e1a86151eef

# PySoy's models.Axis class
#
# Copyright (C) 2006,2007,2008 PySoy Group
#
#  This program is free software; you can redistribute it and/or modify
#  it under the terms of the GNU Affero General Public License as published
#  by the Free Software Foundation, either version 3 of the License, or
#  (at your option) any later version.
#
#  This program is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU Affero General Public License for more details.
#
#  You should have received a copy of the GNU Affero General Public License
#  along with this program; if not, see http://www.gnu.org/licenses
#
# $Id: Axis.pym 1361 2008-09-11 05:50:16Z ArcRiley $

cdef class Axis (Model) :
  '''soy.models.Axis

    This L{models class<soy.models>} renders a "XYZ axis" oriented to each 
    body it's attached to.  This is useful for debugging.
  '''

  ############################################################################
  #
  # WindowLoop Functions
  #

  cdef void _render(self, soy.bodies.Body _body) :
    cdef VertPC      _vert[2]     # contains vertex position and color data
    cdef Line        _elmt[1]     # contains indices to verts to render lines
    cdef gl.GLfloat  _mtx[16]
    #
    ######################################
    #
    # get model's matrix
    #
    _mtx[0]  = _body._rotation[0]
    _mtx[1]  = _body._rotation[4]
    _mtx[2]  = _body._rotation[8]
    _mtx[3]  = 0.0
    _mtx[4]  = _body._rotation[1]
    _mtx[5]  = _body._rotation[5]
    _mtx[6]  = _body._rotation[9]
    _mtx[7]  = 0.0
    _mtx[8]  = _body._rotation[2]
    _mtx[9]  = _body._rotation[6]
    _mtx[10] = _body._rotation[10]
    _mtx[11] = 0.0
    _mtx[12] = _body._position[0]
    _mtx[13] = _body._position[1]
    _mtx[14] = _body._position[2]
    _mtx[15] = 1.0
    #
    ######################################
    #
    # save Camera matix before transforming to the Axis' matrix
    #
    gl.glPushMatrix()
    gl.glMultMatrixf(_mtx)
    #
    ######################################
    #
    # Test if we've already setup the axis VBO
    #
    if self._vertBuffer :
      #
      # Since we already setup the buffers during the first _render, now we
      # just need to re-bind them to render again
      #
      gl.glBindBufferARB(gl.GL_ARRAY_BUFFER_ARB, self._vertBuffer)
      gl.glBindBufferARB(gl.GL_ELEMENT_ARRAY_BUFFER_ARB, self._elementBuffer) 
      #
    else:
      #
      # This is the first render pass, so we need to setup the VBO
      #
      # First we'll populate _vert
      #
      self._vert[0].px = 0.00          # \
      self._vert[0].py = 0.00          #  } (0.0, 0.0, 0.0)
      self._vert[0].pz = 0.00          # /
      self._vert[0].cr = 1.00          # \
      self._vert[0].cg = 0.00          #  } Red
      self._vert[0].cb = 0.00          # /___________________________
      self._vert[1].px = 1.00          # \
      self._vert[1].py = 0.00          #  } (1.0, 0.0, 0.0)
      self._vert[1].pz = 0.00          # /
      self._vert[1].cr = 1.00          # \
      self._vert[1].cg = 0.00          #  } Red
      self._vert[1].cb = 0.00          # /___________________________
      #
      # Next populate _elmt
      #
      self._elmt[0].a = 0              # Line 0: 0-1
      self._elmt[0].b = 1              # ____________________________
      #
      # Create new vertex buffer and send _vert
      #
      gl.glGenBuffersARB(1, &self._vertBuffer)
      gl.glBindBufferARB(gl.GL_ARRAY_BUFFER_ARB, self._vertBuffer)
      gl.glBufferDataARB(gl.GL_ARRAY_BUFFER_ARB, sizeof(_vert), _vert, 
                         gl.GL_STATIC_DRAW_ARB)
      #
      # Do the same for the element buffer
      #
      gl.glGenBuffersARB(1, &self._elmtBuffer)
      gl.glBindBufferARB(gl.GL_ARRAY_BUFFER_ARB, self._elmtBuffer)
      gl.glBufferDataARB(gl.GL_ARRAY_BUFFER_ARB, sizeof(_elmt), _elmt,
                         gl.GL_STATIC_DRAW_ARB)
    #
    ######################################
    #
    # Disable unused pointers
    #
    #   Unlike Mesh and most other models, Axis doesn't use normals or textures
    #   so we need to turn these off while rendering an Axis
    #
    gl.glDisableClientState(gl.GL_NORMAL_ARRAY)         # No Normals
    gl.glDisableClientState(gl.GL_TEXTURE_COORD_ARRAY)  # No Texture Coords
    #
    ######################################
    #
    # Enable color pointer
    #
    #   To get color data into the vertices without making three separate
    #   rendering calls we turn on the color array while rendering
    #
    gl.glEnableClientState(gl.GL_COLOR_ARRAY) # We need to render with color arrays
    #
    gl.glVertexPointer(3, gl.GL_FLOAT, 0,               <gl.GLvoid *> 0)
    gl.glColorPointer (3, gl.GL_FLOAT, sizeof(float)*3, <gl.GLvoid *> 0)
    gl.glDisable(gl.GL_CULL_FACE)
    gl.glDisable(gl.GL_DEPTH_TEST)
    gl.glDisable(gl.GL_LIGHTING)
    gl.glDrawElements(gl.GL_LINES, 2, gl.GL_UNSIGNED_BYTE, <gl.GLvoid *> 0)
    gl.glEnable(gl.GL_LIGHTING)
    gl.glEnable(gl.GL_DEPTH_TEST)
    gl.glEnable(gl.GL_CULL_FACE) 
    gl.glDisableClientState(gl.GL_COLOR_ARRAY)
    gl.glEnableClientState(gl.GL_TEXTURE_COORD_ARRAY)
    gl.glEnableClientState(gl.GL_NORMAL_ARRAY)
    #
    ######################################
    #
    # return to camera matrix
    #
    gl.glPopMatrix()
    #
    ######################################